10 REM QUASATRON ELECTRONICS 8-21-87 (KCM)
20 CLS
30 KEY OFF
40 LOCATE 4,6:PRINT CHR$(201);STRING$(66,205);CHR$(187)
50 LOCATE 5,6:PRINT CHR$(186):LOCATE 5,73:PRINT CHR$(186)
60 LOCATE 6,6:PRINT CHR$(186):LOCATE 6,30:PRINT "QUASATRON ELECTRONICS":LOCATE 6,73:PRINT CHR$(186)
70 LOCATE 7,6:PRINT CHR$(186):LOCATE 7,29:PRINT STRING$(23,126):LOCATE 7,73:PRINT CHR$(186)
80 LOCATE 8,6:PRINT CHR$(186):LOCATE 8,73:PRINT CHR$(186)
90 LOCATE 9,6:PRINT CHR$(186):LOCATE 9,22:PRINT "VSWR CALCULATION AND METER CALIBRATION":LOCATE 9,73:PRINT CHR$(186)
100 LOCATE 10,6:PRINT CHR$(186):LOCATE 10,73:PRINT CHR$(186)
110 LOCATE 11,6:PRINT CHR$(186):LOCATE 11,73:PRINT CHR$(186)
120 PRINT "     ";CHR$(186);"      THIS PROGRAM WILL CALCULATE VOLTAGE STANDING WAVE RATIO     ";CHR$(186)
130 PRINT "     ";CHR$(186);"      FOR TWO VALUES OF VOLTAGE OR POWER ALONG A TRANSMISSION     ";CHR$(186)
140 PRINT "     ";CHR$(186);"      LINE.  IT WILL ALSO CALCULATE A RANGE OF VSWR'S FOR TWO     ";CHR$(186)
150 PRINT "     ";CHR$(186);"        GIVEN VALUES OF POWER USING A PRESELECTED INCREMENT.      ";CHR$(186)
160 LOCATE 16,6:PRINT CHR$(186):LOCATE 16,73:PRINT CHR$(186)
170 LOCATE 17,6:PRINT CHR$(200);STRING$(66,205);CHR$(188)
180 PRINT:PRINT:PRINT:PRINT
190 LET L=0
200 PRINT "        FOR VSWR CALCULATION ENTER 1.   FOR METER CALIBRATION ENTER 2."
210 INPUT "                                      ";Z:
220 CLS
230 IF Z=2 THEN GOTO 700
240 IF Z<>1 THEN GOTO 180
250 PRINT "                               VSWR CALCULATION":PRINT:PRINT
260 INPUT "          WHICH METHOD?   FOR VOLTAGE ENTER 1.  FOR POWER ENTER 2.  ";A
270 PRINT:PRINT:PRINT
280 IF A=2 THEN GOTO 400
290 IF A<>1 THEN GOTO 250
300 INPUT "                            ENTER FORWARD VOLTAGE ";E1:PRINT:PRINT
310 INPUT "                            ENTER REVERSE VOLTAGE ";E2:PRINT:PRINT:PRINT
320 IF E2>E1 THEN GOTO 550
330 IF E1=E2 THEN GOTO 600
340 LET S=((E1+E2)/(E1-E2))
350 LET S=S*1000
360 LET S=INT(S)
370 LET S=S/1000
380 PRINT "                                  VSWR = ";S;":1":FOR Q=1 TO 4:PRINT:NEXT Q
390 GOTO 520
400 INPUT "                            ENTER FORWARD POWER ";P1:PRINT:PRINT
410 INPUT "                            ENTER REVERSE POWER ";P2:PRINT:PRINT:PRINT
420 IF P2>P1 THEN GOTO 550
430 IF P1=P2 GOTO 600
440 LET P=SQR(P2/P1)
450 LET S1=1+P
460 LET S2=1-P
470 LET S=S1/S2
480 LET S=S*1000
490 LET S=INT(S)
500 LET S=S/1000
510 PRINT "                                  VSWR = ";S;":1":FOR Q=1 TO 6:PRINT:NEXT Q
520 INPUT "                  AGAIN? PRESS 1           FINISHED? PRESS 2";F
530 IF F=2 GOTO 990
540 CLS:GOTO 180
550 PRINT "             YOU GOTTA BE KIDDING!  FORWARD LEVEL SHOULD BE HIGHER."
560 PRINT "                      IF NOT YOU HAVE BIG TROUBLE AMIGO!!":PRINT
570 PRINT "                         TRY AGAIN WITH A CORRECT VALUE"
580 PRINT:PRINT:PRINT:PRINT
590 GOTO 200
600 CLS:PRINT "                  ******     *****     *****    *******    **"
610 PRINT "                  *     *   *     *   *     *   *         ****"
620 PRINT "                  *     *   *     *   *     *   *         ****"
630 PRINT "                  ******    *     *   *     *   ******     **"
640 PRINT "                  *         *     *   *     *   *          **"
650 PRINT "                  *         *     *   *     *   *"
660 PRINT "                  *          *****     *****    *          **"
670 PRINT:PRINT:PRINT
680 PRINT "                        YOUR TRANSMITTER JUST BLEW UP !!"
690 GOTO 180
700 CLS
710 PRINT "                       INCREMENTAL VSWR METER CALIBRATION":PRINT:PRINT
720 INPUT "                     ENTER LOWEST POSSIBLE REFLECTED POWER ";P2
730 PRINT:PRINT
740 INPUT "                           ENTER MAXIMUM FORWARD POWER ";P1
750 PRINT:PRINT
760 INPUT "                     ENTER POWER INCREMENT PER CALCULATION ";P3
770 PRINT:PRINT:PRINT
780 IF P2>P1 THEN GOTO 550
790 IF P2=P1 THEN GOTO 600
800 CLS:PRINT "                   REFL. POWER                    VSWR"
810 LET R=SQR(P2/P1)
820 LET S1=1+R
830 LET S2=1-R
840 LET S=S1/S2
850 LET S=S*1000
860 LET S=INT(S)
870 LET S=S/1000
880 IF L=20 THEN GOTO 960
890 PRINT "                      ";P2;"                     ";S;":1"
900 LET L=L+1
910 LET P2=P2+P3
920 IF P1=P2 THEN GOTO 520
930 IF P2<P1 THEN GOTO 810
940 IF P2>P1 THEN GOTO 520
950 STOP
960 INPUT "                           TO CONTINUE, HIT ENTER ";L1
970 LET L=0
980 GOTO 800
990 CLS
1000 INPUT "               STOP? ENTER  1            BACK TO DOS? ENTER  2 ";D
1010 IF D=2 THEN SYSTEM
1020 STOP